home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Apple II Magazines (PO)
/
Bits and Bytes Volume 11, No. 05 (1989-11)(Apple Computing Enjoyment Society)(Side B).zip
/
Bits and Bytes Volume 11, No. 05 (1989-11)(Apple Computing Enjoyment Society)(Side B).po
/
PROGRAMS
/
MOIRE.bas
< prev
next >
Wrap
BASIC Source File
|
1996-12-24
|
950b
|
34 lines
100 REM MOIRE PROGRAM
110 ONERR GOTO 370
130 HOME : VTAB 24
140 HGR : REM SET HI-RESOLUTION GRAPHICS
150 A = RND(1) *279
160 B = RND(1) *159
170 N = INT( RND(1) *7) +2
180 PRINT : PRINT : PRINT
190 HTAB 10: PRINT "MOIRE PICTURE"
200 FOR X = 0 TO 278 STEP N
210 IF PEEK(49152) >127 THEN GOTO 400
220 FOR S = 0 TO 1
230 HCOLOR= 7 *S
240 REM DRAW LINE THRU "CENTER" TO OPPOSITE SIDE
250 HPLOT X +S,0 TO A,B TO 279 -X -S,159
260 NEXT S,X
270 FOR Y = 0 TO 158 STEP N
280 FOR S = 0 TO 1
290 HCOLOR= 7 *S
300 REM SAME AS 240
310 HPLOT 279,Y +S TO A,B TO 0,159 -Y -S
320 NEXT S,Y
330 FOR PAUSE = 1 TO 300: REM DELAY LOOP
340 IF PEEK(49152) >127 THEN GOTO 400
350 NEXT PAUSE
360 GOTO 140: REM DRAW A NEW PATTERN
370 REM
380 REM EXIT ROUTINE
390 REM
400 POKE 49168,0: REM CLEAR KEY CHECK
410 PRINT : PRINT "MOIRE": PRINT "DEMONSTRATION FINISHED"
420 PRINT "PRESS 'RETURN' TO EXIT";
430 INPUT "";A$
460 END